Strings

• STRING
• SUB-STRINGS
• INDEX
• LASTINDEX
• UPCASE
• LOWCASE
• SIZEOF
• TRIM
• F2ASCII
• TOKEN

 

 
 
 

Strings are delimited by double quotes, as in "string". For example:
 

"This is a string"


Strings can be concatenated with the '+' operator. For example:
 

%name = "my" + "file" + "name"


stores "myfilename" in the variable name, and
 

%newname = %name + "." + %(112)


stores "myfilename.112" in newname Special characters are \n for newline, \t for tab, \\ for \, and \" for ".

STRING

% ( <expression> )

The operator % converts braced <expression> into a string. Example:
 

println %( 1+4-2 )


prints 3.

SUB-STRINGS

sub-strings are created by given the string + range

Example 1:
 

%test = "123456789"
println %test[3..8]


prints: 345678

Example 2:
 

%test = "123456789"
println %test [2..4,6,8..9]


prints 234689

Copy a (sub)-string into a sub-string

Example 3:
 

%test = "123456789"
%test[2] = "a"
println %test


prints 1a3456789

Example 4:
 

%test = "123456789"
%test[2..4] = "abcdefgh"
println %test


prints 1abc56789

Example 5:
 

%test = "123456789"
%test[2..] = "abcd"
println %test


prints 1abcd6789

Example 6:
 

%test = "123456789"
%test[2..] = "abcdefghijklm"
println %test


prints 1abcdefghijklm

Example 7:
 

%test = "123456789"
%test[12] = "a"
println %test


prints 123456789  a

Example 8:
 

# test is not defined before
%test[12] = "a"
println "1" + %test


prints 1            a
 

INDEX

index( <string> , <sub-string> )

The function index gives the first starting position of the sub-string <sub-string> in the string <string>. If <sub-string> does not match any part of <string>, -1 is returned.Example:
 

$i = index("abcdef","cd")


returns 3 into the variable i

LASTINDEX

lastindex( <string> , <sub-string> )

The function lastindex gives the last starting position of the sub-string <sub-string> in the string <string>. If <sub-string> does not match any part of <string>, -1 is returned.Example:
 

%name = "/usr/local/myfile"
$i = lastindex(%name,"/")
if $i != -1 then
    %name = %name[$i+1 ..]
endif


returns "myfile" into the variable "name"

UPCASE

upcase ( <string> )

The function upcase converts the string <string> in upper case characters. Example:
 

%test = upcase("abcde")
println %test


prints: ABCDE

LOWCASE

lowcase ( <string> )

The function lowcase converts the string <string> in lower case characters. Example:

%test = lowcase("abCDE")
println %test


prints: abcde

SIZEOF

sizeof( <string> )

Returns the number of characters in <string>.

TRIM

trim ( <string> )

The function trim removes white space ( \n \r \t and ' ' ) at the end of the string <string>. Example:
 

%test = trim("abcde  ") + "fg"
println %test


prints: abcdefg

F2ASCII

f2ascii ( <array> )  or f2ascii ( <value> )

The function f2ascii converts a float or array ( of floats ) into an ascii string. All bytes of the float(s) are returned as characters in the string if they represent a printable 7bits ascii character. Otherwise they are replaced by spaces. Each float produces a 4-character string-part.

Example 1:
 

# open binary acqu file
$fn = open "acqus", "r"
# read 1 float = 4 bytes
$test = read $fn
# convert
println f2ascii($test)


prints A000 Example 2:
 

# open new_style text acqu file
$fn = open "acqus", "r"
# read 2 floats = 8 bytes
@a[1..2] = read $fn
# convert
println f2ascii(@a[1..2])


prints ##TITLE=

TOKEN

<value> = token { <inputstring> , } <delimiter>

This is an implementation of C's strtok(), that can parse <inputstring> into tokens.  The first call to token is with two arguments, an input string and a delimiter, and the first token is returned in <value> . For all further calls only one argument is used, the delimiter, and the next token is returned. The delimiter may be different for each call. If no more tokens are available, an empty string is returned. Unlike in C, the input string is not destroyed.

Example 1:

%line = " abc 1234; ok;twelve eleven;1.99"

%bla = token %line, " ;"
while %bla != "" do
    println %bla
    %bla = token " ;"
done

prints

abc
1234
ok
twelve
eleven
1.99